Epedemic
Man schreibt das Jahr 1989. Ein Meteoritenschwarm droht mit der Erde zu kollidieren und eine weltweite Katastrophe auszulösen. Auf den Meteoriten befinden sich Viren, die eine tödliche Seuche verursachen. Es liegt an Ihnen, das Spiel mit möglichst wenig Verlusten an Menschenleben und einer unverseuchten Erde zu beenden.
Nach dem Laden und Starten des Programms erscheint zunächst die Frage, wieviele Verluste Sie sich zugestehen. Diese Zahl darf maximal vierstellig eingegeben werden. Danach erscheint die erste Bildschirmanzeige mit der Angabe des Tages (jede Spielrunde entspricht einem Spieltag), der Anzahl der anfliegenden Meteoriten und deren augenblickliche Entfernung von der Erde. Außerdem wird die Gesamtbevölkerung sowie die Verlustquote angezeigt.
Durch Betätigen der Funktionstaste F1 wechseln wir ins zweite Bild. Hier erhält man einen Überblick über den Stand der Dinge in den acht Regionen des Aktionsfeldes (Tabelle 1). Angezeigt wird für jede Region die Bevölkerungszahl sowie etwaige Verluste.
| Region | Millionen Einwohner |
|---|---|
| Asien | 2738 |
| UdSSR | 312 |
| Europa | 576 |
| Afrika | 480 |
| Australien | 24 |
| Nordamerika | 310 |
| Südamerika | 362 |
| Wasser | — |
| gesamt | 4802 |
Durch nochmaliges Drücken von F1 gelangt man nun endlich ins Aktionsbild. Hier gibt es vier Aktionsmöglichkeiten, von denen jedoch nur eine pro Spieltag erlaubt ist.
Haben Sie sich für die medizinische Versorgung einer Region entschieden und den entsprechenden Menüpunkt ausgewählt, dann erscheint auf dem Bildschirm eine Übersicht über die verseuchten Regionen mit Schlüsselnummer und Level. Der Level ist die prozentuale Verlustquote der Bevölkerung. Dazu wird der Medikamentenvorrat angezeigt, und es erscheint die Frage nach der Region. Geben Sie an dieser Stelle die Schlüsselziffer der gewählten Region ein.
Es erscheint eine Angabe über die benötigte Menge an Medikamenten für die Versorgung dieser Region. Diese Menge wird von dem Gesamtvorrat an Medikamenten abgezogen und Sie kehren automatisch ins Hauptmenü zurück.
Sie können versuchen, einige der anfliegenden Meteore präventiv mit Raketen abzuschießen. Haben Sie sich hierfür entschieden, dann werden zunächst alle in Frage kommenden Meteore aufgelistet.
Achtung ! Der Wirkungsradius der Raketen beträgt zwischen 15000 und 50000 Kilometer. Meteore außerhalb dieses Entfernungsbereiches können nicht mit Raketen bekämpft werden.
Sie brauchen sich jetzt nur zu entscheiden, welchen Meteor Sie angreifen wollen. Der Raketenstart erfolgt vollautomatisch; allerdings trifft nicht jede Rakete ihr Ziel.
Falls eine der Regionen so hochgradig verseucht ist, daß selbst massiver Medikamenteneinsatz keine Aussicht auf Erfolg mehr verspricht, bleibt als letzte Lösung nur noch die nukleare Vernichtung der gesamten Region, um ein Übergreifen der Seuche auf andere Regionen zu verhindern. Wenn Sie sich dafür entschieden haben, erhalten Sie zunächst eine Übersicht über alle verseuchten Regionen, deren Bevölkerungszahl schon auf weniger als die Hälfte der ursprünglichen Anzahl gesunken ist.
Geben Sie jetzt die Schlüsselzahl der entsprechenden Region ein. Wenn Sie es sich in der Zwischenzeit doch anders überlegt haben, tippen Sie an dieser Stelle nur eine Null ein.
Die Produktion von Medikamenten ist die letzte der vier Aktionsmöglichkeiten. Auf dem Bildschirm erscheint eine Auflistung der unverseuchten Regionen und die dort jeweils produzierte Menge an Medikamenten. Diese Menge richtet sich nach der jeweiligen Bevölkerungsanzahl. Die Region mit der größten Bevölkerung hat auch den größten Ausstoß an Medikamenten. Beachten Sie, daß nur in völlig unverseuchten Regionen produziert wird.
Als reines Informationsbild gibt es die Weltgrafik. Auf dem Bildschirm wird eine Karte dargestellt, in die der Grad der Verseuchung in den einzelnen Regionen eingetragen ist. Die Verseuchung wird dabei in fünf Stufen angezeigt, nämlich unverseucht, bis 25, 50, 75 oder 100 Prozent verseucht. Da diese Weltgrafik nur zur Übersicht dient und Sie hier keine Entscheidung treffen können, gelangen Sie nach Betätigen einer Taste wieder zurück ins Menü, von wo aus Sie wieder alle vier Entscheidungsmöglichkeiten haben.
Die Meteore haben eine Geschwindigkeit von ungefähr 9000 Kilometern pro Tag. Hat man die erste Meteorwelle erfolgreich bekämpft, folgen weitere Meteore nach. Erst nach 30 Tagen Aktionszeit stürzen keine weiteren Meteore mehr auf die Erde ein, und das Spiel kann ausklingen. Nach 60 Tagen schließlich ist das Spiel auf jeden Fall beendet.
Ein Meteoraufschlag fordert zwei Millionen Todesopfer direkt und durch Verseuchung sofort weitere fünf Millionen Tote. Jeder weitere Tag, an dem die Seuche in der betreffenden Region nicht bekämpft wird, bedingt weitere fünf Millionen Tote.
Ist eine Region total verseucht, so können die Nachbarländer infiziert werden. Eine weitsichtige, strategische Planung der Seuchenbekämpfung ist daher unumgänglich.
Der Schwierigkeitsgrad des Spieles ist zugegebenermaßen nicht gerade niedrig. Nur wer die Nerven behält und weitsichtig plant, wird letzten Endes die völlige Auslöschung der Menschheit, zumindest im Spiel, verhindern können.
(Wolf-D. Robrahn/ev)10 rem"epidemic"
15 poke36879,168
20 printchr$(14)
25 print"{clr}{down}{down}{down}{down}{down}{rght}{rght}{rght}{rght}(c) 1983 by"
30 print"{down}{rght}{rght}{rght}Wolf-D.Robrahn"
35 print"{down}{rght}{rght}{rght}Beethovenstr.18
40 print"{down}{rght}{rght}{rght}2200 Elmshorn
50 fort=1to5000:next
51 printchr$(142)
52 print"{clr}{blk}{down}{down}{down}{down}{down}{down}{down}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}"
53 print" e p e d e m i c"
54 print" {CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}{CBM-+}"
55 poke36879,11
60 fora1=25to249step32
65 poke36879,a1
70 fort=1to1000:next
75 next
80 poke36879,25
100 forr1=1to200
110 r2=int(rnd(1)*126)+4250
120 poker2,81:poker2+33792,r3
130 r3=r3+1:ifr3=8thenr3=0
140 ifr3=1thenr3=2
150 next
155 print"{home}"
160 fora1=1to462
170 print"{wht}{rvon} ";:next
190 printchr$(14)
200 print"{clr}{red}wieviele Verluste gestehen Sie sich bei Ihrer strategischen Fuehrung";
210 print" ein?"
220 print"{down}{down}Gesamtbev. "
230 print"{rvon}4802{rvof} Mill.Einwohner"
240 print"{down}{down}{rght}{rght}{rght}{rght}{rght}{rght}Mill.Einwohner"
250 input"{up}";a$
260 by=val(a$)
498 mz=50:rk=35
499 poke36879,25:printchr$(144)
500 rem anzahl meteor
520 a=13
530 dimme(a)
540 fora1=1toa
545 a3=int(rnd(1)*4e4)+9e4
550 me(a1)=a3
560 next
570 goto700
600 rem meteor entf.
620 fora1=1toa
630 a3=int(rnd(1)*8e4)+3e4
640 me(a1)=a3
650 next
655 ifbb=1then1400
700 rem variablen
730 da=1:po=4802:px=po
750 a$(5)=" AUSTRAL.:"
751 a$(1)=" ASIEN:"
752 a$(3)=" EUROPA:"
753 a$(6)="NORDAMER.:"
754 a$(7)="SUEDAMER.:"
755 a$(4)=" AFRIKA:"
756 a$(2)=" UdSSR:"
757 a$(8)=" WASSER:"
758 a$(9)=" WASSER:"
770 po(1)=2738:po(3)=576:po(6)=310:po(7)=362:po(4)=480:po(2)=312:po(5)=24
775 fora1=1to7:px(a1)=po(a1):next:bb=1
815 printchr$(14)
950 fort1=1to3000:next
1400 rem total status
1415 fora1=1to9:ifp1(a1)=0thennext:goto1500
1420 print"{clr}{rght}Zustand fuer Tag:"da
1430 print"{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}{CBM-R}{CBM-E}"
1435 print"{rvon} Region Aufschl. "
1440 fora1=1to9
1445 ifp1(a1)=0then1460
1450 printa$(a1)," ##"
1460 next
1465 print"{down}{down}{down} weiter mit f1"
1470 getx$:ifx$<>chr$(133)then1470
1480 fora1=1to9:p1(a1)=0:next
1500 rem total status
1515 poke36879,25
1520 printchr$(14)
1530 print"{clr}{rght}{blk}Zustand fuer Tag:"da
1540 print"{rght}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}{SHIFT-*}"
1550 print"{rvon}Meteor Entfernung {rvof}"
1560 fora1=1toa
1565 ifme(a1)<=0andme(a1)=>-10000thenprint"Nr."a1tab(11)"{rvon}{red}AUFSCHLAG{blk}":goto1580
1567 ifme(a1)<-10000thenprint"Nr."a1tab(11)"{rvon}{grn}*ABSCHUSS{blk}":goto1580
1570 print"Nr." tab(3)a1tab(9)"{CBM--}"me(a1)tab(19)"km"
1580 next
1590 print"{rght}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}{CBM-POUND}"
1600 print"{rvon}ges.Bev. {rvof}"potab(17)"Mill"
1610 print"{rvon}Verluste:{rvof}"vetab(17)"Mill"
1620 print"{cyn} weiter mit f1{blu}"
1630 getx$:ifx$<>chr$(133)then1630
1660 print"{clr}{rght}Zustand fuer Tag:"da
1670 print"======================"
1680 print"{rvon}Region Bevoelkerung"
1690 fora1=1to7
1700 print"{rvon}"a$(a1)"{rvof}"tab(10) po(a1)tab(17)"Mill"
1710 next
1720 print" {rvon}Verluste "
1730 fora1=1to7
1740 print"{rvon}"a$(a1)"{rvof}"tab(10)ve(a1)tab(17)"Mill"
1750 next
1755 print"{cyn} weiter mit f1{blu}"
1760 getx$:ifx$<>chr$(133)then1760
1800 poke36879,76
1805 print"{clr}{rvon}{yel}Treffen Sie Ihre Ent- scheidung zur Rettung der Erdbevoelkerung! "
1810 print
1820 print"<1> medizin.Versorg. einer Reg."
1830 print"<2> Raketenabschuss zur Vernichtung eines Meteors"
1840 print"<3> nukleare Vern. einer Region"
1850 print"<4> Produktion von Medikamenten"
1855 print"<5> Seuchenzustand in Weltgrafik"
1860 input"{rvon}{down}{down}{down}Schluesselzahl{rvof}";sz
1870 fort=1to500:next
1900 rem abzweigung
1930 ifsz=1then10000
1940 ifsz=2then20000
1950 ifsz=3then30000
1960 ifsz=4then40000
1965 ifsz=5then50000
1970 ifsz<=0orsz>5then1860
2400 rem var.berech.
2500 fora1=1toa
2505 ifme(a1)=-15000then2550
2510 ifme(a1)>0thenme(a1)=me(a1)-9000
2520 ifme(a1)<=0andme(a1)>-10000thenme(a1)=0
2530 ifme(a1)<-10000thenme(a1)=-15000
2540 ifme(a1)=0thengosub6000:me(a1)=-10000:c(b)=1:p1(b)=1
2550 next
2590 ve=0
2600 fora1=1to7
2610 ifc(a1)=0then2640
2620 po(a1)=po(a1)-5:ifpo(a1)<0thenpo(a1)=0
2625 ve(a1)=px(a1)-po(a1)
2630 ep(a1)=int((1000*ve(a1))/px(a1))/10
2640 ve=ve+ve(a1)
2645 ifep(a1)>=100andc(a1)=1thenc(a1+1)=1:c(a1-1)=1
2800 next
2900 da=da+1:po=px-ve:ifpo<0thenpo=0
2950 ifve=>bythen60000
2960 ifda>=60then60000
4600 fora1=1to13
4610 ifme(a1)<=0andda>30thennext:goto5100
4700 fora2=1toa
4710 ifme(a2)<=0thennext:goto 600
5000 goto1400
5100 fora1=1to7
5110 ifc(a1)=0thennext:goto60000
5120 goto1400
6000 rem aufschl.ziel
6020 b=int(rnd(1)*9)+1
6030 po(b)=po(b)-2:return
10000 rem med.vers.
10020 poke36879,59:printchr$(144)
10030 print"{clr}{rvon} medizinische Versorgung "
10040 print"{blu}{rght}verseuchte Regionen"
10050 print
10060 print"{blk}{rvon} Region Nr Level "
10065 fora1=1to7:ifc(a1)=0thennext:goto60500
10070 fora1=1to7
10075 ifc(a1)=0then10100
10080 ifep(a1)<=0then10100
10085 ifve(a1)=px(a1)thenprint"{rvon}"a$(a1)"{rvof}"tab(9)a1tab(15)" TOT":goto10100
10090 print"{rvon}"a$(a1)"{rvof}"tab(9)a1 tab(13)ep(a1)tab(19)"%"
10100 next
10110 print">>>>>>>>>>><<<<<<<<<<<"
10115 print"MED.VORRAT:"mz"t"
10120 input"{rvon}welche Region{rvof}";a4
10125 print"{down}{down}noetige Menge:"ve(a4)"t"
10127 ifve(a4)>mzthenprint"{down}NICHT{$a0}GENUG{$a0}VORRAT":goto10140
10130 mz=mz-ve(a4)
10135 print"{down}MED.VORRAT:"mz"t"
10137 c(a4)=0
10140 fort=1to3000:next
10150 goto2500
20000 rem raketenab.
20010 poke36879,170:printchr$(28)
20015 print"{clr}{rvon}{rght}{rght}{rght}Raketenabschuss"
20030 print"{down}{blk}{rvon}Raketenreichweite = 50000 km {red}"
20035 print"{rvon} Meteor Entfernung "
20036 ifc(1)>0andc(2)>0andc(3)>0andc(4)>0andc(5)>0andc(6)>0andc(7)>0then21000
20037 fora1=1toa:ifme(a1)<15000orme(a1)>50000thennext:goto60300
20040 fora1=1toa
20050 ifme(a1)>50000orme(a1)<15000then20120
20060 print"Nr. "a1tab(10)me(a1)"km"
20120 next
20125 print"**********************"
20130 print"Potential:"rk"Raketen"
20135 ifrk=0then23000
20140 print"{down}1 Rakete fuer"
20150 input"welchen Meteor";a5
20155 gosub22000
20160 ifa1=1ora1=2then me(a5)=-15000
20170 a1=0:rk=rk-1
20180 goto2500
21000 print"KEIN{$a0}ABSCHUSS{$a0}MOEGLICHDA{$a0}ALLE{$a0}REGIONEN{$a0}VER-{$a0}SEUCHT"
21001 print"{down}DRINGEND{$a0}MED.HILFE{$a0}{$a0}{$a0}{$a0}ERFORDERLICH!"
21002 fort=1to8000:next
21005 goto20180
22000 a1=int(rnd(1)*3)+1:ifa1=3thenprint"{blu}****ZIEL{$a0} VERFEHLT****{red}":fort=1to5000:next
22005 return
23000 print"{down}IHR{$a0}POTENTIAL{$a0}IST{$a0}{$a0}{$a0}{$a0}{$a0}ERSCHOEPFT!"
23010 fort=1to5000:next:goto2500
30000 rem nukl.det.
30020 poke36879,127
30030 print"{clr}{blk} nukleare Vernichtung"
30035 print"**********************"
30040 print"{down}um den Befall der Viren auf andere Regionen zu vermeiden"
30050 print"ist es noetig eine Region total zu zer- stoeren."
30055 print"{down}{rvon} Region Nr. Level "
30060 fora1=1to7
30070 ifc(a1)=1andep(a1)>50then30080
30075 goto30150
30080 printa$(a1)tab(10)a1tab(14)ep(a1)tab(19)"%"
30150 next
30160 input"{down}welche Region";b1
30170 po(b1)=0:c(b1)=0:ve(b1)=px(b1)
30180 goto2500
40000 rem prod.med.
40015 poke36879,158:printchr$(144)
40030 print"{clr}{rvon}Medikamente Produktion"
40040 print"Sie koennen nur in un-verseuchten Regionen produzieren!"
40045 print"{down}{rvon} Region t Medik. "
40049 aa=0
40050 fora1=1to7
40060 ifc(a1)=1then40120
40070 mk(a1)=int(po(a1)/80)
40075 printa$(a1)tab(13)mk(a1)
40080 aa=aa+mk(a1)
40120 next
40125 mz=mz+aa
40130 print"{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}{CBM-B}"
40140 print"{rvon}Med.Vorrat:{rvof}"mz"t"
40150 fort=1to5000:next
40160 goto2500
50000 rem weltkarte
50012 poke36879,104:printchr$(142)
50015 print"{clr}{wht} weltkarte"
50017 forb4=37932to38327:pokeb4,7:next
50019 gosub51000
50020 forq=1to183
50030 readkl
50040 readkj
50050 pokekl,kj
50060 next
50065 poke4558,160:poke4536,160:poke38350,4:poke38328,7
50066 print"{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{down}{rght}{rght}unverseucht"
50067 print"{rght}{rght}verseucht"
50070 getx$:ifx$=""then50070
50080 restore
50090 printchr$(14)
50100 goto1800
50500 data4140,108,4141,254,4142,252,4143,98,4144,98,4145,123,4156,100,4159,111,4160,100
50510 data4162,236,4163,160,4164,160,4165,160,4166,160,4167,160,4168,108,4173,254
50520 data4174,252,4175,123,4176,108,4177,254,4178,160,4179,160,4180,160,4181,160
50530 data4182,160,4183,126,4185,126,4186,251,4187,160,4188,160,4189,160,4190,160
50540 data4191,123,4195,120,4196,225,4197,160,4198,160,4199,160,4200,160,4201,160
50550 data4202,160,4203,160,4204,234,4208,106,4209,160,4210,160,4211,160,4212,236
50560 data4216,108,4217,254,4218,160,4219,160,4220,160,4221,160,4222,160,4223,160
50570 data4224,160,4225,160,4226,236,4230,245,4231,160,4232,160,4233,236,4238,254
50580 data4239,160,4240,160,4241,160,4242,160,4243,160,4244,160,4245,160,4246,160
50590 data4247,160,4252,160,4253,160,4254,251,4259,108,4260,236,4261,124,4262,123
50600 data4263,245,4264,160,4265,160,4266,160,4267,160,4268,160,4269,160,4270,116
50610 data4274,117,4275,160,4276,124,4281,124,4282,126,4284,126,4285,254,4286,160
50620 data4287,160,4288,160,4289,160,4290,160,4291,236,4297,236,4303,254,4304,160
50630 data4305,247,4306,123,4307,160,4308,160,4309,160,4310,160,4311,160,4312,160
50640 data4313,97,4319,127,4320,123,4325,160,4326,160,4327,160,4328,160,4329,95
50650 data4330,105,4331,225,4332,97,4333,95,4334,236,4342,127,4343,252,4344,123
50660 data4347,160,4348,160,4349,160,4350,160,4351,123,4353,106,4354,101,4356,251
50670 data4364,160,4365,160,4366,252,4370,251,4371,160,4372,160,4373,97
50680 data4378,123,4386,245,4387,160,4388,160,4389,116,4392,106,4393,160,4394,160
50690 data4395,101,4400,127,4408,225,4409,160,4410,160,4411,101,4414,103,4415,160
50700 data4416,160,4430,106,4431,160,4432,236,4437,251,4438,231,4445,254
50710 data4446,254,4452,245,4453,160,4454,97,4459,225,4460,126,4467,251
50720 data4468,236,4474,118,4475,236,4496,103,4497,117,4519,126
50730 data4324,106,4298,59,4292,118
51000 rem************
51010 rem ber.grafik
51020 rem************
51030 ifc(1)=1then52000
51040 ifc(2)=1then52100
51050 ifc(3)=1then52200
51060 ifc(4)=1then52300
51070 ifc(5)=1then52400
51080 ifc(6)=1then52500
51090 ifc(7)=1then52600
51100 return
52000 ifep(1)<25thenc2=22:c3=0:c4=0:c5=0:c6=0:c7=0:goto53000
52010 ifep(1)<=50thenc2=22:c3=44:c4=0:c5=0:c6=0:c7=0:goto53000
52020 ifep(1)<=75thenc2=22:c3=44:c4=66:c5=88:c6=0:c7=0:goto53000
52030 ifep(1)<=100thenc2=22:c3=44:c4=66:c5=88:c6=110:c7=132:goto53000
52100 ifep(2)<=25thenc2=22:c3=0:c4=0:c5=0:goto54000
52110 ifep(2)<=50thenc2=22:c3=44:c4=0:c5=0:goto54000
52120 ifep(2)<=75thenc2=22:c3=44:c4=66:c5=0:goto54000
52130 ifep(2)<=100thenc2=22:c3=44:c4=66:c5=88:goto54000
52200 ifep(3)<=25thenc2=22:c3=0:c4=0:c5=0:c6=0:goto55000
52210 ifep(3)<=50thenc2=22:c3=44:c4=0:c5=0:c6=0:goto55000
52220 ifep(3)<=75thenc2=22:c3=44:c4=66:c5=0:c6=0:goto55000
52230 ifep(3)<=100thenc2=22:c3=44:c4=66:c5=88:c6=110:goto55000
52300 ifep(4)<=25thenc2=22:c3=0:c4=0:c5=0:c6=0:c7=0:c8=0:goto56000
52310 ifep(4)<=50thenc2=22:c3=44:c4=66:c5=0:c6=0:c7=0:c8=0:goto56000
52320 ifep(4)<=75thenc2=22:c3=44:c4=66:c5=88:c6=110:c7=0:c8=0:goto56000
52330 ifep(4)<=100thenc2=22:c3=44:c4=66:c5=88:c6=110:c7=132:c8=154:goto56000
52400 ifep(5)=<25thenc2=0:c3=0:c4=0:goto57000
52410 ifep(5)<=50thenc2=1:c3=0:c4=0:goto57000
52420 ifep(5)<=75thenc2=1:c3=22:c4=0:goto57000
52430 ifep(5)<=100thenc2=1:c3=22:c4=23:goto57000
52500 ifep(6)<=25thenc2=22:c3=0:c4=0:c5=0:c6=0:c7=0:c8=0:goto58000
52510 ifep(6)<=50thenc2=22:c3=44:c4=0:c5=0:c6=0:c7=0:c8=0:goto58000
52520 ifep(6)<=75thenc2=22:c3=44:c4=66:c5=88:c6=0:c7=0:c8=0:goto58000
52530 ifep(6)<=100thenc2=22:c3=44:c4=66:c5=88:c6=110:c7=132:c8=154:goto58000
52600 ifep(7)<=25thenc2=22:c3=44:c4=0:c5=0:c6=0:c7=0:c8=0:c9=0:cc=0:goto59000
52610 ifep(7)<=50thenc2=22:c3=44:c4=66:c5=88:c6=0:c7=0:c8=0:c9=0:cc=0:goto59000
52620 ifep(7)<=75thenc2=22:c3=44:c4=66:c5=88:c6=110:c7=132:c8=0:c9=0:cc=0:goto59000
52630 ifep(7)<=100thenc2=22:c3=44:c4=66:c5=88:c6=110:c7=132:c8=154:c9=176:cc=198
52640 goto59000
53000 forc1=38056to38062
53010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4:pokec1+c5,4:pokec1+c6,4:pokec1+c7,4
53030 next:goto51040
54000 forc1=37946to37953
54010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4:pokec1+c5,4
54020 next:goto51050
55000 forc1=37963to37967
55010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4:pokec1+c5,4:pokec1+c6,4
55020 next:goto51060
56000 forc1=38094to38099
56010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4:pokec1+c5,4:pokec1+c6,4:pokec1+c7,4
56015 pokec1+c8,4
56020 next:goto51070
57000 forc1=38237to38237
57010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4
57020 next:goto51080
58000 forc1=37932to37939
58010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4:pokec1+c5,4:pokec1+c6,4:pokec1+c7,4
58015 pokec1+c8,4
58020 next:goto51090
59000 forc1=38110to38115
59010 pokec1,4:pokec1+c2,4:pokec1+c3,4:pokec1+c4,4:pokec1+c5,4:pokec1+c6,4:pokec1+c7,4
59015 pokec1+c8,4:pokec1+cc,4
59020 next:goto51100
60000 rem************
60010 rem ende
60020 rem************
60030 poke36879,154
60040 print"{clr}{blk} Spielende"
60050 ifve=>bythengosub60100
60060 ifve<bythengosub60200
60070 print"Ergebnis:"
60075 print"{down}ges.Bev.:"po"Mill"
60080 print"{down}Verluste:"ve"Mill"
60090 print"{down}Aktionsdauer:"da"Tage"
60095 end
60100 print"{down}{down}SIE{$a0}HABEN{$a0}DAS{$a0}SPIEL{$a0}{$a0}{$a0}VERLOREN!"
60150 return
60200 print"{down}{down}SIE{$a0}HABEN{$a0}DAS{$a0}SPIEL{$a0}{$a0}{$a0}GEWONNEN!"
60250 return
60300 print"{down}{down}{down}kein Ziel in Aussicht!"
60310 fort=1to2000:next:goto2500
60500 print"{down}{down} zur Zeit keine Verseuchung"
60510 print"{down}{down}{rvon}med.Vorrat:{rvof}"mz"t"
60515 fort=1to5000:next:goto2500
Diesen Artikel als PDF herunterladen
Diesen Artikel auf Mastodon teilen